-
Articoli
-
Cari amici del Forum,
vi scrivo per chiedere il vostro aiuto su alcune formule contenute nella cartella. Nelle celle G4, H4 e I4 sono presenti 3 formule separate che fanno riferimento alla tabella rinominata “tbl_consulenti”. Mi chiedevo se fosse possibile ottenere lo stesso risultato con un’unica formula da inserire nella cella G4 e che si espanda anche nelle altre 2 colonne (Ore totali ed Attività). Potreste darmi per favore qualche suggerimento? Grazie come sempre a chi vorrà dedicare un po' del suo tempo. La versione utilizzata è Microsoft 365 Apps for enterprise. Un caro saluto
ciao
=LET(C;RAGGRUPPAPER(Tbl_consulenti[[#Tutti];[COGNOME]]&" "&Tbl_consulenti[[#Tutti];[NOME]];Tbl_consulenti[[#Tutti];[ORARIO]];SOMMA;3;0);STACK.ORIZ(C;INCLUDI(Tbl_consulenti[[#Tutti];[INCARICO]];CONTA.NUMERI(C)+1)))
anche se sono sicuro che ci sia da ritoccare se lo stesso personaggio ha due incarichi
Ciao gianfranco55,
la tua formula funziona perfettamente. Ora la studio per capire bene la sintassi ed imparare qualcosa di nuovo.
Purtroppo temo che quanto da te ipotizzato (dipendente con più incarichi) possa avverarsi, ad ogni modo proverò a trovare una soluzione. Se non riesco scriverò ancora sul Forum. Grazie ancora per la tua disponibilità. Un caro saluto
ciao,
altre soluzioie con output leggermente diverso
1) tabella pivot (risultato come in figura)
2) formula
=PIVOTPER(Tbl_consul enti[COGNOME]&" "&Tbl_consulenti[NOME]&" "&D4:D12;;Tbl_consulenti[ORARIO];SOMMA;;0)
Ciao LukeReds, grazie innanzitutto per il tuo intervento.
Ho provato la formula e l'output che restituisce va bene e mi permette, peraltro, di gestire la situazione in cui lo stesso dipendente ricopra incarichi diversi.
Un caro saluto,
ciao
luk
mettimi il file
perchè la tua formula rende 2 colonne
concatena nome cognome incarico
e somma.
ciao Gf,
si l'output non è identico a quello proosto altrimenti si dovrebbe allungare la formula con testo unisci, dividi testo ecc ecc. La tabella pivot invece ha le colonne distinte.
Buon pomeriggio a t e ed a Franci70
PS: mi capita spesso di inserire un post ma, cliccando"invia", questo viene eliminato. Misteri del forum...
ciao
l'idea è quella io ho usato
RAGGUPPAPER()
e se franci mi conferma che ci possono essere più incarichi per lo stesso nome
vario l'ultima parte per renderla flessibile
colonne staccate (pesonalmente creerei una tabella pivot)
=LET(s;DIVIDI.TESTO(TESTO.UNISCI("\";;UNICI(Tbl_consulenti[COGNOME]&"_"&Tbl_consulenti[NOME]&"_"&Tbl_consulenti[INCARICO]));"_";"\");STACK.ORIZ((DIVIDI.TESTO(TESTO.UNISCI("\";;UNICI(Tbl_consulenti[COGNOME]&"_"&Tbl_consulenti[NOME]&"_"&Tbl_consulenti[INCARICO]));"_";"\"));PERRIGA(SCEGLI.COL(s;1)&SCEGLI.COL(s;2)&SCEGLI.COL(s;3);LAMBDA(r;SOMMA((Tbl_consulenti[COGNOME]&Tbl_consulenti[NOME]&Tbl_consulenti[INCARICO]=r)*(Tbl_consulenti[ORARIO]))))))
Più corta
=STACK.ORIZ(DATI.ORDINA(DIVIDI.TESTO(TESTO.UNISCI("\";;UNICI(Tbl_consulenti[COGNOME]&"_"&Tbl_consulenti[NOME]&"_"&Tbl_consulenti[INCARICO]));"_";"\"));SCEGLI.COL(PIVOTPER(Tbl_consulenti[COGNOME]&Tbl_consulenti[NOME]&Tbl_consulenti[INCARICO];;Tbl_consulenti[ORARIO];SOMMA;;0);2))
ciao
non la provo ma ad occhio manca il pezzo finale della formula
sì vero avevo fatto un copia "ristretto", ho correrto grazie
Ciao gianfranco 55 e LukeReds,
grazie ancora per la vostra disponibilità, ho imparato molto dai vostri post.
Si gianfranco55, ti confermo che ci possono essere più incarichi per la stessa persona.
Un caro saluto,
Ciao LukeReds,
ho provato la formula e funziona molto bene!
Ora la studio attentamente.
Grazie ancora per la disponibilità.
Un caro saluto,
Ciao
2 esempi sullo stesso foglio
=SE.ERRORE(LET(C;RAGGRUPPAPER(Tbl_consulenti[[#Tutti];[COGNOME]]&" "&Tbl_consulenti[[#Tutti];[NOME]];Tbl_consulenti[[#Tutti];[ORARIO]];SOMMA;0;0;;Tbl_consulenti[[#Tutti];[INCARICO]]=E1);STACK.ORIZ(C;MAP(SEQUENZA(CONTA.NUMERI(C)); LAMBDA(x; E1))));"")
=SE.ERRORE(RAGGRUPPAPER(Tbl_consulenti[[#Tutti];[COGNOME]]&" "&Tbl_consulenti[[#Tutti];[NOME]];Tbl_consulenti[[#Tutti];[ORARIO]];SOMMA;0;0;;Tbl_consulenti[[#Tutti];[INCARICO]]=G18);"")
Ciao gianfranco55,
grazie ancora per la tua disponibilità. Ho scaricato il file ed ora lo studio.
Un caro saluto,
Login
Registrati
Stai vedendo 15 articoli - dal 1 a 15 (di 15 totali)
Stai vedendo 15 articoli - dal 1 a 15 (di 15 totali)