-
Articoli
-
Ciao a tutti
Sarà il caldo, mà non riesco trovare la formula idonea.
Devo trovare i tre prezzi più costosi per ogni categoria senza usare la colonna E.
Grazie in anticipociao,
non so se è un mio problema ma non riesco a scaricare il file.....
.. sono riuscito, in J8 e trascini a dx ed in basso (ctrl shift enter). La formula non usa la colonna E
=GRANDE(SE($B$2:$B$50=J$7;$C$2:$C$50*(1-$D$2:$D$50));4-RIF.RIGA(A1))
ciao
in J8 matriciale ctrl maiuscolo invio (se hai il 365 avvisa)
=GRANDE(SE($B$2:$B$100=J$7;$E$2:$E$100);RIF.RIGA($A1))
la tiri a destra e in basso
@lukereds, grazie perfetta
@gianfranco55, >>>senza usare la colonna E
Se volessi pure la somma dei tre, dovrei fare GRANDE(SE(…);1)+GRANDE(SE(…);2)+GRANDE(SE(…);3)
Ps. Non esiste altra formula senza usare il Matriciale (ho paura che diventi pesante con migliaia di righe)ciao
la versione per favore
Excel 2019
ciao
prova questa matriciale ctrl maiuscolo invio
=SOMMA(GRANDE(C2:C100*(1-D2:D100)*(B2:B100="N");{1\2\3}))
per vere formule più performanti dovresti passare almeno al 2021
ma visto che con 10/20 euro trovi il 2024 ti consiglierei quest'ultimo.
il 2019 è un ibrido che ancora non ha l'espansione
Ok grazie
Ps Questa mi funziona senza usare matriciale, però non so come abinarla ad una categoria
=INDICE(GRANDE(($C$2:$C$21)-(($C$2:$C$21)*($D$2:$D$21));{1\2\3});1;1)+INDICE(GRANDE(($C$2:$C$21)-(($C$2:$C$21)*($D$2:$D$21));{1\2\3});1;2)+INDICE(GRANDE(($C$2:$C$21)-(($C$2:$C$21)*($D$2:$D$21));{1\2\3});1;3)
EDIT forse ho trovato =INDICE(GRANDE((B2:B21="N")*($C$2:$C$21)-(($C$2:$C$21)*($D$2:$D$21));{1\2\3});1;1)+ecc ecc
EDIT carino il (1-$D$2:$D$21)......=INDICE(GRANDE((B2:B21="N")*($C$2:$C$21)*(1-$D$2:$D$21);{1\2\3});1;1)+ecc ecc
ciao
ma a quel punto
usa
=INDICE(GRANDE(C2:C100*(1-D2:D100)*(B2:B100="N");RIF.RIGA(A1));;1)
è corta e non dovrebbe essere necessario confermarla matriciale
@gianfranco55. Ottimo, grazie mille
Ultima richiesta, mi sono reso conto che lo sconto non è sotto forma percentuale.
In colonna D c'è scritto un numero esempio per riga_2 cella D2 ------> 99 al posto di 1%
In teoria sarebbe =(C2/100)*D2
Questa la formula =INDICE(GRANDE(($B$2:$B$100="M")*(($C$2:$C$100/100)*(E2:$E$100));RIF.RIGA(A1));;1)
Più snella non si riesce?ciao
=GRANDE(SE($B$2:$B$50=J$7;$C$2:$C$50*($D$2:$D$50/100));4-RIF.RIGA(A1))
@lukereds, con Excel-2019 la Tua è matriciale
Grazie a tutti, ho risolto con =INDICE(GRANDE(($B$2:$B$100="M")*($C$2:$C$100*($E$2:$E$100/100));1);;1)
qual'è il problema delle formule matriciali?
Poi stai usando la colonna E, che dicevi di non voler usare.......Ad ogni modo se tu avessii centinaia di migilaia di righe potresti optare per le power query oppure con una tabella pivot tipo questa
Stavo usando un altro files…
=INDICE(GRANDE(($B$2:$B$100="M")*($C$2:$C$100*($D$2:$D$100/100));1);;1)Nessun problema, solo una questione di pelle. Non mi piacciono le Matriciali, le Function e non sono bravo con Grafici e Pivot. Un saluto
Ciao a tutti, con la funzione Aggrega (che incorpora anche Grande) sicuramente non c'è bisogno del matriciale però non sono sicuro se col 2019 sia disponibile
Qui ci vuole Gianfranco
ciao
in J8 da tirare e destra e in basso
=AGGREGA(14;6;$E$2:$E$100/($B$2:$B$100=J$7);RIF.RIGA($A1))
il 2019 non ha l'espansione altrimenti si poteva usare
=AGGREGA(14;6;$E$2:$E$21/($B$2:$B$21=J$7);RIF.RIGA($1:$3))
Effettivamente leggermente più corta, grazie ancora.
Aggrega è presente come minimo da excel 2013
ciao Luk e Luca
dal 2010 è presente AGGREGA()
ciao Gf, infatti ho scritto "come minimo".....
Poi la storia delle formule non mi appassiona più di tato
Io l'ho sempre detto che ci capisco poco di formule
Poi la storia delle formule non mi appassiona più di tanto
a differenza mia che le adoroooooooooo
Login
Registrati
Stai vedendo 22 articoli - dal 1 a 22 (di 22 totali)
Stai vedendo 22 articoli - dal 1 a 22 (di 22 totali)