Ma la richiesta e' tutto senza codice? Solo formule?

Ciao @semiuccio

dunque io purtroppo sto facendo un po' fatica a capire ciò che ti serve. Quello che ho capito è che tu hai:

1 foglio "CATEGORIE" dove elenchi tutte le categorie delle varie spese che sostieni

1 foglio relativo all'anno dove elenchi le spese sostenute

1 foglio "Spese Ricorrenti" dove elenchi tutte quelle che sono le spese cicliche (quelle che sei certo di dover pagare), comprese di date e somme.

Ora, da quel poco che ho inteso, tu vorresti elencare nel foglio "2025" tutte le spese, ma quelle così dette "Ricorrenti", vorresti che ti comparissero in automatico quando la data attuale è relativa alla data di scadenza della Spesa Ricorrente.

Quindi, per ipotesi, nel foglio 2025, nella prima cella utile in colonna A scrivi una data, ad esempio quella di oggi (19/01/2025), poi compili da colonna B a colonna D i vari dati (categoria, tipo e importo). Poi attraverso un pulsante, importi tutte quelle spese ricorrenti relative alla data attuale. Dopodiché aggiungere una "x" di fianco alla spesa ricorrente presa in considerazione. Cosicché, al prossimo lancio della macro, quella spesa non viene più presa in considerazione.

Provo a girarti un mio esempio. Vedi se ho capito.

Tieni presente che ho eliminato il rigo 2 (che risultava nascosto) nel foglio "2025" perché credo che non abbia alcuna utilità.

In oltre per far sì che tutto funzioni, devi riportare esattamente le stesse parole nei fogli "CATEGORIE" e "Spese Ricorrenti". Cioè la scritta "Internet casa" deve essere uguale in entrambi i fogli...e non che in uno c'è scritto "Internet casa" e nell'altro "Internet"

Bene, sono contento che abbiamo risolto.

Semiuccio ha scritto:

mi riprometto di approfondire tutto il codice

Per facilitare la comprensione ti ho messo un commento per ogni azione:

Option Explicit

Sub speseRicorrenti()
    Dim c As Range, f As Range
    Dim ur As Long, newRow As Long
    Dim categoria As String
    
    '--qui si capisce...giusto?
    If MsgBox("Sei sicuro di voler aggiornare i dati con le ""Spese Ricorrenti""?", vbQuestion + vbYesNo, "Spese ricorrenti") = vbNo Then Exit Sub
    
    '--rileva il numero della riga compilata nel foglio "Spese Ricorrenti"
    ur = Sheets("Spese Ricorrenti").Cells(Rows.Count, "A").End(xlUp).Row
    
    '--esegue un ciclo su ogni cella del foglio "Spese Ricorrenti" che va dalla cella A2 all'ultima riga compilata (ur)
    For Each c In Sheets("Spese Ricorrenti").Range("A2:A" & ur)
        '--se la data presente nella cella iterata è inferiore o uguale alla data attuale e _
           nella colonna "D" (Registrata) non è presente la "x" allora...
        If CLng(c) <= CLng(Date) And c.Offset(, 3) <> "x" Then
            '--ricava il primo rigo disponibile nel foglio "2025" (quindi ultimo rigo compilato + 1)
            newRow = Sheets("2025").Cells(Rows.Count, "A").End(xlUp).Row + 1
            '--formatta in data la cella in colonna "A"
            Sheets("2025").Range("A" & newRow).NumberFormat = "m/d/yyyy"
            '--formatta in valuta la cella in colonna "D"
            Sheets("2025").Range("D" & newRow).NumberFormat = "#,##0.00 $"
            '--cerca la "spesa" nel foglio "Categorie"
            Set f = Sheets("CATEGORIE").Cells.Find(What:=c.Offset(, 1), LookIn:=xlValues, LookAt:=xlWhole)
            '--se non è nulla...ovvero se l'ha trovata...
            If Not f Is Nothing Then
                '--assegna alla variabile 'categoria' il TIPO di categoria definito nel rigo 1 del foglio "Categorie". _
                   Preleva quindi prendendo come coordinare rigo 1 e colonna trovata (f.Column)
                categoria = Sheets("CATEGORIE").Cells(1, f.Column).Value
            End If
            
            Sheets("2025").Range("A" & newRow).Value = c.Value '--assegna alla cella A e nuovo rigo la data ciclata
            Sheets("2025").Range("B" & newRow).Value = categoria '--assegna alla cella B e nuovo rigo la 'categoria'
            Sheets("2025").Range("C" & newRow).Value = c.Offset(, 1).Value '--assegna alla cella B e nuovo rigo la spesa ciclata
            Sheets("2025").Range("D" & newRow).Value = c.Offset(, 2).Value '--assegna alla cella C e nuovo rigo l'importo ciclato
            
            c.Offset(, 3).Value = "x" '--segna una 'x' nella cella D ciclata
        End If
    Next c
    
    MsgBox "Fatto!"
End Sub