Controlli oggetto Baloon

Vediamo ora un esempio di utilizzo dei pulsanti nei fumetti dell'assistente.

Sub FumettoPulsante()

    Dim selez As Long
    Dim Ass As Office.Balloon
    Set Ass = Assistant.NewBalloon
    With Ass
        .Icon = msoIconAlertInfo
        .Heading = "Prova pulsanti"
        .Text = "Utilizzo dei pulsanti di un Fumetto"
        .Button = msoButtonSetYesNoCancel
        selez = .Show
    End With
    Select Case selez
    Case msoBalloonButtonYes
        Assistant.Animation = msoAnimationGestureLeft
        Ass.Text = "Hai selezionato 'Si'"
        Ass.Button = msoButtonSetOK
        Ass.Show
    Case msoBalloonButtonNo
        Assistant.Animation = msoAnimationGestureRight
        Ass.Text = "Hai selezionato 'No'"
        Ass.Button = msoButtonSetOK
        Ass.Show
    Case msoBalloonButtonCancel
        Assistant.Animation = msoAnimationEmptyTrash
    End Select
End Sub

La proprietà Button dell'oggetto Balloon imposta la serie di pulsanti da inserire nel fumetto. Nel nostro caso: SI, NO, ANNULLA. All'interno della istruzione Case Select, e dopo avere eseguito il metodo Show, la routine valuta quale pulsante è stato premuto ed esegue le istruzioni associate.

I possibili valori di Button e quindi le possibili combinazioni di pulsanti possibili sono:

    msoButtonSetAbortRetryIgnore
    msoButtonSetBackClose
    msoButtonSetBackNextClose
    msoButtonSetBackNextSnooze
    msoButtonSetCancel
    msoButtonSetNextClose
    msoButtonSetNone
    msoButtonSetOK
    msoButtonSetOkCancel
    msoButtonSetRetryCancel
    msoButtonSetSearchClose
    msoButtonSetTipsOptionsClose
    msoButtonSetYesAllNoCancel
    msoButtonSetYesNo
    msoButtonSetYesNoCancel

Il metodo "Show" oltre a visualizzare l 'oggetto fumetto restituisce una costante MsoBalloonButtonType che indica su quale pulsante o etichetta viene fatto clic.

I possibili valori di ritorno sono:

    msoBalloonButtonAbort
    msoBalloonButtonBack
    msoBalloonButtonCancel
    msoBalloonButtonClose
    msoBalloonButtonIgnore
    msoBalloonButtonNext
    msoBalloonButtonNo
    msoBalloonButtonNull
    msoBalloonButtonOK
    msoBalloonButtonOptions
    msoBalloonButtonRetry
    msoBalloonButtonSearch
    msoBalloonButtonSnooze
    msoBalloonButtonTips
    msoBalloonButtonYes
    msoBalloonButtonYesToAll

Lo stesso messaggio poteva essere visualizzato con l'istruzione MsgBox.

Sub MsgPulsante()

    Dim selez As Long
    Dim Intest As String
    Dim Descriz As String
    
    Intest = "Prova pulsanti"
    Descriz = "Esempio di utilizzo dei pulsanti di un MsgBox"
    selez = MsgBox(Descriz, vbYesNoCancel, Intest)

    Select Case selez
    Case vbYes
        MsgBox "Hai selezionato Si", vbInformation, "Intest"
    Case vbNo
        MsgBox "Hai selezionato No", vbInformation, "Intest"
    End Select
End Sub

Vediamo ora un esempio di utilizzo delle Caselle di controllo nei fumetti.

Sub CasellaControllo()

    Dim Ass As Office.Balloon
    Set Ass = Assistant.NewBalloon
    With Ass
        .Icon = msoIconTip
        .Heading = "Casella di Controllo "
        .Text = "Esempio di utilizzo delle" & _ 
	"Caselle di controllo." & _
	" Dopo l'elaborazione apri la" & _ 
	"finestra immediata e vedere il risultato."
        .CheckBoxes(1).Text = "Voce 1"
        .CheckBoxes(2).Text = "Voce 2"
        .CheckBoxes(3).Text = "Voce 3"
        .Show
        If .CheckBoxes(1).Checked Then
            Debug.Print "Hai selezionato la Voce 1"
        End If
        If .CheckBoxes(2).Checked Then
            Debug.Print "Hai selezionato la Voce 2"
        End If
        If .CheckBoxes(3).Checked Then
            Debug.Print "Hai selezionato la Voce 3"
        End If
    End With
End Sub

La proprietà CheckBoxes(numero).Text inserisce una nuova casella di controllo nel fumetto. All'interno della istruzione Case Select, e dopo avere eseguito il metodo Show, la routine valuta quale casella è stata selezionata ed esegue le istruzioni associate.