funzioni a più variabili

Hai un problema con Excel?

Nuova discussione

funzioni a più variabili
di ax1978go (utente non iscritto) data: 29/04/2015 19:03:21
Ciao a tutti.
non sono molto esperto di excel, ho meglio le cose che fino ad oggi sapevo bastavano, ma ora mi trovo a calcolare una funzione con più variabili ma non riesco a impostarla.
vi descrivo il quesito sperando in una vostra risposta:

la formula che devo riportare é: ((variabile-D7)*C4*D8). la "variabile" può assumere tre valori in base al valore che assumerà D7

C4 = Ore lavorative
C5 = Contratti prodotti
D7 = C4/C5
D8 = Retribuzione netta oraria

la costante per avviare la formula è che C5>14

i valori che D7 può assumere sono i seguenti:
se D7>=3 nella formula si userà una variabile E5=6.5
se D7 ha un valore compreso tra 2,99 e 1,90 la variabile da usare è F5=7
se D7<1,89 nella formula si userà la variabile G5=8

io avevo impostato così la formula:
=SE(E((C5>14);(D7>=3));((E5-D7)*C4*D8));SE(E((C5>14);(D7>=1,9);(D7<=2,99));((F5-D7)*C4*D8));SE(E((C5>14);(D7<=1,89));((G5-D7)*C4*D8))

ma nella casella mi compare la scritta "#VALORE!"
potreste aiutarmi a capire come impostare correttamente la formula.
vi ringrazio già in anticipo.
di Luca73 data: 30/04/2015 08:52:16
Ciao
allora
primo punto cosa succede se C5<=14?
secondo punto
la funzione se ha un costrutto del tipo
SE(condizione;severo;sefalso)
se vuoi nidificarlo dovresti avere qualcosa del tipo
SE(condizione1;severo1;SE(condizione2;severo2;sefalso2))
e via discorrendo
Nella tua formula sono sbagliate le formule nel senso che prima del secondo SE hai chiuso il primo completamente.
la tua corretta dovrebbe essere
=SE(E((C5>14);(D7>=3));((E5-D7)*C4*D8);SE(E((C5>14);(D7>=1.9);(D7<=2.99));((F5-D7)*C4*D8);SE(E((C5>14);(D7<=1.89));((G5-D7)*C4*D8))))
però così non capisci il caso C5<=14 diventa solo e soltanto l'ultimo.
intuendo che sotto 14 qualcosa cambia io la scriverei così:
=SE(C5<=14;"Valore<14";C4*D8*(SE(D7>=3;E5-D7;SE(D7>=1.9;F5-D7;G5-D7))))
Ciao
Luca
funzioni a più variabili
di ax1978go (utente non iscritto) data: 30/04/2015 09:47:05
Ciao Luca e grazie,ho provato la mia formula che hai modificato e ora funziona.
per rispondere alla tua domanda se C5<14 la casella della formula dovrà rimanere vuota perché in quel caso interverrà una nuova formula posta in un'altra casella.

ti ringrazio ancora e ti auguro una buona giornata.
di Luca73 data: 30/04/2015 13:13:56
Prego quindi la formula sarà
=SE(C5<=14;"";C4*D8*(SE(D7>=3;E5-D7;SE(D7>=1.9;F5-D7;G5-D7))))
o ancora più compatta
=SE(C5<=14;"";C4*D8*(SE(D7>=3;E5;SE(D7>=1.9;F5;G5)-D7)))
Ciao
se La discussione è Risolta fleggala come tale

Vuoi Approfondire?