cerca verticale personalizzato

Hai un problema con Excel?

Nuova discussione

cerca verticale personalizzato
di pordenones data: 07/02/2013 11:31:41
buongiorno,
ho un file excel cosi composto
colonna A elenco di codici e poi nel range colonna da G ad O ho diverse macchine che possono essere prodotte.
i codici della colonna A si possono trovare sia nella colonne G che nella H con varie quantità.
Io avrei bisogno di cercare i codici della colonna A nel range che va dalla colonna G alla colonna O e sapere dove trovo una quantità insertita.
cioè io non so a priori quale colonna mostrare come risultato del cerca verticale. La colonna da mostrare cambia in funzione della macchina in cui il codice è presente.
Non so come fare per avere questo risultato .
Ancora piu bello sarebbe che mi si restituisse come risultato l'intestazione della colonna ( che nel file rappresenta il nome della macchina in cui il codice è presente .
non posso caricare il file ma sono a completa disposizione per chiarimenti
grazie

saluti
VERSIONE
di canapone (utente non iscritto) data: 07/02/2013 12:07:20

Ciao,

due domande: con quale versione di Excel lavori e in quali colonne trovo i codici e le quantità.

Immagino che i codici sono su due o tre colonne e le relative unità nelle colonne subito accanto.

Saluti
di pordenonese (utente non iscritto) data: 07/02/2013 16:18:11
uso excel 2003.
i codici sono tutti solo sulla colonna A poi diciamo che si intersecando con le altre colonne.
Dalla G alla O ci sono tutte le versione delle macchine.
Alcuni codici possono avere quantità presenti anche in macchine diverse quindi colonne diverse .
di canapone (utente non iscritto) data: 07/02/2013 16:31:34

Ciao,

la formula somma tutte le quantità in G2:O1000 in corrispondenza della riga che contiene il codiceX (colonna A)

=MATR.SOMMA.PRODOTTO((A$2:A$1000="codiceX")*G$2:O$1000)

Spero sia d'aiuto
di pordenonese (utente non iscritto) data: 08/02/2013 09:01:13
no. cosi somma i numeri ma non mi restituisce la colonna dove trova il dato.
io ho una lista di codici e devo dire ( confrontando questo file con un altro identico ma gia completato ) dove si trovano i codici , cioè in quale macchina .
Ogni colonna dalla G contiente come intestazione il modello macchina e come riga la quantità del codice in quella macchina
indice matrice
di canapone (utente non iscritto) data: 08/02/2013 10:25:57
Ciao,

condivido un piccolo file d'esempio dove uso un INDICE in forma matrice che confronta il codice in A12 ed estrae le intestazioni colonna dova trova le quantità

=SE(VAL.ERRORE(INDICE($A$1:$O$1;PICCOLO(SE(INDICE($A$3:$O$6;CONFRONTA($A$12;$A$3:$A$6;0);)>0;RIF.COLONNA($A$3:$O$6));RIF.COLONNA(B1))));"";INDICE($A$1:$O$1;PICCOLO(SE(INDICE($A$3:$O$6;CONFRONTA($A$12;$A$3:$A$6;0);)>0;RIF.COLONNA($A$3:$O$6));RIF.COLONNA(B1))))

Forse può servire.

Saluti
di canapone (utente non iscritto) data: 08/02/2013 10:33:58
Ciao,

riscrivo il segmento principale della formula (se servisse)

=INDICE($A$1:$O$1;PICCOLO(SE(INDICE($A$3:$O$6;
CONFRONTA($A$12;$A$3:$A$6;0);)>0;RIF.COLONNA($A$3:$O$6));
RIF.COLONNA(B1)))

Su Excel 2003 ho parcheggiato la formula dentro VAL.ERRORE

=se(val.errore(formula);"";formula)

Formula da confermare con control+maiusc+invio

Saluti
di pordenonese (utente non iscritto) data: 08/02/2013 11:30:42
potresti spiegarmi cosa fa la formula?
alcune non le conosco
inoltre cosa c'è nella colonna B ? nel mio caso ci sono le descrizioni dei codici vorrei capire grazie mille
saluti
di canapone (utente non iscritto) data: 08/02/2013 12:01:36
Ciao,
provo a dare qualche indicazione.

INDICE($A$3:$O$6;CONFRONTA($A$12;$A$3:$A$6;0);)>0

produce una serie di 0;1 a condizione di essere sulla riga che contiene A12 il codice X) e che le celle della riga contengano un valore maggiore di 0.

Per far leggere come una matrice questo segmento al resto della formula, non ho chiuso l'INDICE, non ho indicato la colonna dove andare a cercare.

Potevo scriverlo anche così

INDICE($A$3:$O$6;CONFRONTA($A$12;$A$3:$A$6;0);0)>0

La serie di 0/1 è moltiplicata da RIF.COLONNA($A$3:$O$6)

Puoi scrivere anche RIF.COLONNA($A$1:$O$1): produce semplicemente una serie di numeri da 1 a 16. Equivale a RIF.RIGA($A$1:$A$16)

Moltiplicando le due matrici rimangono solo i numeri delle colonne "piene"

Fra questi numeri fa la selezione PICCOLO che scegli prima il secondo pieno - con RIF.COLONNA(B1) poi il terzo rif.colonna(B1)... Il numero serve all'INDICE(A1:O1;...
per ottenere l'intestazione della colonna: nell'esempio le intestazioni sono sulla riga 1.

Per adattare la formula, ora sappiamo che la colonna B contiene delle descrizioni

Sicuramente non interessa l'intestazione della colonna B, quindi si fa partire la ricerca dalla terza colonna ">0" RIF.COLONNA(C1)

INDICE($A$1:$O$1;PICCOLO(SE(INDICE($A$3:$O$6;
CONFRONTA($A$12;$A$3:$A$6;0);)>0;RIF.COLONNA($A$3:$O$6));
RIF.COLONNA(C1)))

Non so se è questo che ti serve.

Saluti
di pordenonese (utente non iscritto) data: 08/02/2013 14:15:38
ci ho messo un po di tempo ma ho quasi capito la sua formula.
No .Provo a schematizzare la mia tabella in breve
A B C D
1 CODICE DESCRIZIONE MODELLO 1 MODELLO 2
2 800315 PERNO 5 0
3 568923 CUSPIDE 1 2
4 131545 ATTACCO 0 2

in un altro foglio ho un altro elenco di codici che devo confrontare con quelli che trovo nella colonna A.
e uso un cerca verticale.
Una volta fatto questo devo dire per ogni codice se si trova nel modello 1 oppure nel modello 2 .Non devo dire quanti pezzi ci sono. devo dire in che modello si trova quel determinato codice.oppure se e in tutti e due.
la sua formula fa questo?
grazie
di CANAPONE (utente non iscritto) data: 08/02/2013 14:19:00

Ciao,

sì, recupera le intestazioni delle colonne se nella riga dovre trova il codiceX trova le celle non vuote (con delle quantità ho immaginato).

E' importante che venga confermata come formula matrice (control+maiusc+invio)

Saluti
di CANAPONE (utente non iscritto) data: 08/02/2013 14:31:48

Ciao,

ho messo in condivisione un altro allegato.

Sa servisse
di pordenonese (utente non iscritto) data: 08/02/2013 15:38:57
è veramente proprio quello che volevo grazie.
ora cerchero' di decifrare la formula in quanto è davvero lunga ;)
grazie

Vuoi Approfondire?