Valore Max



  • Valore Max
    di Textomb data: 14/06/2014 01:29:54

    Ragazzi sarà l'orario. Non saprei. Mi sono esaurito...
    Vorrei risolvere la problematica descritta nel file allegato.
    In una tabella con Provincia, Comune, N. Stade, si tratta di trovare la provincia con il più alto numero di strade.
    La difficoltà sta nel fatto che dovrei prima raggruppare tutte le provincie e quindi trovare, per ogni Provincia, il numero totale di strade. Da lì, poi calcolare il valore Max. Io vorrei poter fare tutto in un'unica formula.



  • di ninai (utente non iscritto) data: 14/06/2014 02:39:09

    Ciao
    sarà l'ora e la stanchezza ma l'unica soluzione che mi viene prevede una colonna di appoggio (esempio la D)

    -in D6 : =MATR.SOMMA.PRODOTTO(($B$6:$B$39=B6)*$C$6:$C$39) e trascini in basso

    in F6: =MAX($D$6:$D$39)
    in E6: =INDICE($B$6:$B$39;CONFRONTA(F6;$D$6:$D$39;0))

    il problema nasce qualora lo stesso numero massimo di strade l'hanno più di una provincia. in questo caso , vi è più di un risultato e la formula in E6 si deve modificare.



  • di Textomb data: 14/06/2014 10:18:53

    grazie mille Ninai.
    Immaginavo non si potesse fare con una formula senza utilizzare una colonna di appoggio...



  • di ninai (utente non iscritto) data: 14/06/2014 11:46:45

    No No, credo che si possa fare, sono io che al momento non riesco a "partorirla", vedrai che qualche "lupo" delle matriciali si fa avanti


  • max provincia
    di canapone (utente non iscritto) data: 16/06/2014 14:25:31


    Ciao

    in F6

    =MAX(SOMMA.SE(B6:B39;B6:B39;C6:C39)) da cpnfermare con control+maiusc+invio

    in E6

    =INDICE(B6:B39;CONFRONTA(F6;INDICE(SOMMA.SE(B6:B39;B6:B39;C6:C39););0))

    Fate qualche prova



  • di scossa data: 16/06/2014 15:36:30

    Chapeau!



  • di Textomb data: 16/06/2014 16:30:47

    ottimo Canapone!!!
    A questo punto si potrebbe anche semplificare un pochino:

    in E6 diventa:
    =INDICE(B6:B39;CONFRONTA(F6;SOMMA.SE(B6:B39;B6:B39;C6:C39);0))
    però diventa matriciale... quindi ctrl+maiusc+invio


  • INDICE(CONFRONTA
    di canapone (utente non iscritto) data: 16/06/2014 16:38:40

    Ciao,

    esatto, il secondo INDICE serve solo ad evitare l'uso del control+maiusc+invio.

    Anche nella prima formula - per foruna stiamo lavorando con MAX- potresti usare l'INDICE

    =MAX(INDICE(SOMMA.SE(B6:B39;B6:B39;C6:C39);0))

    Non dovrebbe cambiare nulla.

    Ne approfitto anche per salutare e ringraziare Scossa e Ninai.