Somma totali mensili

Hai un problema con Excel?

Nuova discussione

Somma totali mensili
di Francesco69 (utente non iscritto) data: 11/02/2015 12:23:04
Salve a tutti ho un problema da risolvere ma non so proprio come fare, provo a spiegare,
ho un file dove nella colonna B23:B365 vengono archiviati dei totali, è possibile nella cella C23:C365 tramite formula ogni fine mese mi vengano stampati i totali di ogni mese?
di Luca73 data: 11/02/2015 13:19:26
In colonna A hai le date?
Allega un file di esempio.
Ciao
LT
di Vecchio Frac data: 11/02/2015 13:38:41
Penso che una colonna di date sia indispensabile, come dice Luca73. Altrimenti è impossibile stabilire il range mensile da considerare.
di Francesco69 (utente non iscritto) data: 11/02/2015 18:03:27
Scasate ma mi sono dimenticato di comunicare che la data si trova nella colonna A23:A365
di Raffaele_53 (utente non iscritto) data: 12/02/2015 04:10:05
Intendevi dire visualizzare
Metti in E1:E12 i mesi scritti come numeri 1,2,3 ecc ecc Questa vale solo per l'anno Attuale
In F1 scrivi =MATR.SOMMA.PRODOTTO((A$23:A$365>=DATA(ANNO(OGGI());E1;1))*(A$23:A$365<=DATA(ANNO(OGGI());E1+1;1)-1)*(B$23:B$365))

Se invece hai anche anni precendenti puoi scrivere in
F1 =MATR.SOMMA.PRODOTTO((A$23:A$365>=DATA(2015;E1;1))*(A$23:A$365<=DATA(2015;E1+1;1)-1)*(B$23:B$365)) 'vale solo per 2015 adesso scrivi in
G1 =MATR.SOMMA.PRODOTTO((A$23:A$365>=DATA(2014;E1;1))*(A$23:A$365<=DATA(2014;E1+1;1)-1)*(B$23:B$365)) 'vale solo per 2014 ecc ecc e trascini giù

di Luca73 data: 12/02/2015 09:32:45
Ciao io ho scritto le due formule sotto riportate che a cambio mese calcolano il totale per il mese
La prima scrive il risultato in corrispondenza dell'ultima cella del mese mentre la seconda formula scrive il totale in corrispondenza della prima cella di ogni mese.
La formula va scritta in C23 e poi copiata in tutte le celle sottostanti.

Anche le formule di Raffaele_53 possono essere modificate in modo da renderle indipendenti dall'anno e senza dover aggiungere alcuna colonna di appoggio (Vedi terza formula sotto) e se vuoi che scriva solo all'inizio o a fine mese basta inserirle all'interno di un SE come per le formule 1 e 2.

Ciao

1)
=SE(MESE(A23)<>MESE(A24);SOMMA.PIù.SE(B$23:B$365;A$23:A$365;">=" & DATA(ANNO(A23);MESE(A23);1);A$23:A$365;"<" & DATA(ANNO(A23);MESE(A23)+1;1));"")
2)
=SE(O(MESE(A23)<>MESE(A22);A22="");SOMMA.PIù.SE(B$23:B$365;A$23:A$365;">=" & DATA(ANNO(A23);MESE(A23);1);A$23:A$365;"<" & DATA(ANNO(A23);MESE(A23)+1;1));"")
3)
=MATR.SOMMA.PRODOTTO((A$23:A$365>=DATA(ANNO(A23);MESE(A23);1))*(A$23:A$365<=DATA(ANNO(A23);MESE(A23)+1;1)-1)*(B$23:B$365))

di Francesco69 (utente non iscritto) data: 14/02/2015 15:28:33
Grazie per l'aiuto, ho provato la formuna e funziona grazie

Vuoi Approfondire?