Media ultimi 10 valori

Hai un problema con Excel?

Nuova discussione

Media ultimi 10 valori?
di Jaqen77 data: 02/12/2015 14:28:40
Ciao a tutti, come sempre vi chiedo una mano sicuro che qualcuno mi saprà sicuramente aiutare...
Sulla riga 1 io ho diciamo 100 celle che vado via via a popolare da sx a dx con un valore numerico. È possibile senza passare da VBA avere una formula che mi faccia la media di volta in volta solo degli ultimi 10 valori inseriti?
Grazie mille!
di Luca73 data: 02/12/2015 14:56:09
Prova Con
=MEDIA(SCARTO(A1;0;CONTA.VALORI(1:1)-10;1;10))
di Jaqen77 data: 02/12/2015 15:17:33
Quasi!
Se ci sono celle vuote però va in errore...c'è modo di fargliele ignorare?
di Jaqen77 data: 02/12/2015 15:20:32
No scusa funziona perfettamente!

Grazie mille!!!!
di Santuberto (utente non iscritto) data: 02/12/2015 15:49:21
Buongiorno a tutti.
Spero sia corretto (per non aprire una nuova discussione) aggregarmi per un'altra domanda sullo stesso argomento:e se i valori fossero in colonna?
Grazie a chi mi potrà aiutare.
di Mister_x (utente non iscritto) data: 02/12/2015 16:07:24
ciao

formula matriciale
=MEDIA(INDIRETTO(INDIRIZZO(1;MAX(SE(A1:ZZ1<>"";RIF.COLONNA(A1:ZZ1)))-10)):INDIRETTO(INDIRIZZO(1;MAX(SE(A1:ZZ1<>"";RIF.COLONNA(A1:ZZ1))))))
confermare con ctrl+maius+invio

questa comincia a valutare dalla cella K1 in poi
non so se e' questo che serve per il conteggio, se no bisogna ricorrere ad una funzione in VB che escluda tutte le celle nulle o a stringa e faccia la media solamente alle ultime 10 celle con valore inserito

fai sapere
ciao
di Luca73 data: 02/12/2015 16:12:46
Ciao la stessa di prima con i dati in colonna
=MEDIA(SCARTO(A1;CONTA.VALORI(1:1)-10;0;10;1))

Ciao
Luca
media ultimi 10 valori in colonna
di canapone data: 02/12/2015 16:23:34
Ciao a tutti,

un altro possibile approccio potrebbe essere:

=MEDIA(INDICE(A1:A1000;CONTA.VALORI(A1:A1000)-9):INDICE(A1:A1000;CONTA.VALORI(A1:A1000)))

Saluti
di Mister_x (utente non iscritto) data: 02/12/2015 16:40:14
ciao

ciao luca e canapone
nel caso di conta.valori se noi sia in riga che in colonna abbiamo celle vuote automaticamente l'ultimo valore inserito verrebbe ignorato dal calcolo di media, dato che il conta.valori() rileva solamente celle occupate da Xvalori e non vuote

ciao
di Luca73 data: 02/12/2015 17:01:37
Ciao MisterX
hai perfettamente ragione
prima correzione:
=MEDIA(SCARTO(A1;0;MAX(SE(1:1="";0;RIF.COLONNA(1:1)))-10;1;10))
matriciale

considera le ultime 10 celle a prescindere se siano piene o vuote
di canapone data: 02/12/2015 17:35:29
Ciao Mister_x,

hai ragione.

Avevo letto solo il primo post e la richiesta di Santuberto:

L'idea era di non usare funzioni volatili.

Excel 2010

=SE.ERRORE(MEDIA(INDICE(A1:A1000;AGGREGA(15;6;RIF.RIGA(A1:A1000)/(A1:A1000<>"");CONTA.SE(A1:A1000;"<>")-9)):INDICE(A1:A1000;CONFRONTA(999^99;A1:A1000)));"")

Il confronta può essere sostituito dal corrispondenre AGGREGA( ....;CONTA.SE(A1:A1000;"<>")

Excel 2007 (formula da far digerire con il control+maiusc+invio)

=SE.ERRORE(MEDIA(INDICE(A1:A1000;PICCOLO(SE(A1:A1000<>"";RIF.RIGA(A1:A1000));CONTA.SE(A1:A1000;"<>")-9)):INDICE(A1:A1000;CONFRONTA(999^99;A1:A1000)));"")

Anche nella seconda formula il CONFRONTA può essere sostituito da PICCOLO(SE...

Saluti
di Santuberto (utente non iscritto) data: 02/12/2015 17:51:29
Siete veramente straordinari. Un sincero grazie a tutti tre.
di Mister_x (utente non iscritto) data: 03/12/2015 00:40:27
ciao

tanto per passare il tempo
con funzione indice si elimina il matriciale

per le righe
=MEDIA(SCARTO(A1;MAX(INDICE((A1:A10000<>"")*RIF.RIGA(1:10000);))-10;0;10;1))

per le colonne
=MEDIA(SCARTO(A1;0;MAX(INDICE((1:1<>"")*RIF.COLONNA(1:256);))-10;1;10)) per 2003 ed inferiore
=MEDIA(SCARTO(A1;0;MAX(INDICE((1:1<>"")*RIF.COLONNA(1:10000);))-10;1;10)) per 2007 e sup

ciao
di Santuberto (utente non iscritto) data: 03/12/2015 14:44:35
Buongiorno Mister_x. Complimenti e nuovamente grazie.
Giusto per la precisione: hai invertito colonne e righe. Ma ... appena le usi, te ne accorgi subito!
di Santuberto (utente non iscritto) data: 03/12/2015 15:02:28
E' mai possibile che il mio Excel, inverta le colonne (che dovrebbero essere quelle verticali) con le righe? Per dimostrare che non ho bevuto, allego il file Z EX 34
di Jaqen77 data: 07/12/2015 12:07:49
Scusate, come faccio ad evitare l'errore di riferimento circolare presente sull'ultimo file in allegato?
Si presenta quando - chiedendo una media degli ultimi 10 valori (tramite elenco in A2)- ne sono presenti solo 9; in questi casi vorrei diciamo che sulla cella B3 comparisse solo un trattino "-"....
di Mister_x (utente non iscritto) data: 07/12/2015 13:19:26
ciao

visto adesso la postilla di santuberto , provato sul mio sia in 2007 che 13 ma le formule fanno esattamente riga e colonna , verificato con media ultimi 10 valori in una cella,

per jagen
=SE(CONTA.VALORI($C3:$L3)>=10;MEDIA(SCARTO($C3;0;CONTA.VALORI($C3:$L3)-10;1;10));"-")

adattala anche per 9,6,3

ciao
di Jaqen77 data: 07/12/2015 13:55:24
Ottimo, un grazie enorme ancora una volta!

Vuoi Approfondire?