Sub mail()

'Working in 97-2010
    Dim FileExtStr As String
    Dim FileFormatNum As Long
    Dim Sourcewb As Workbook
    Dim Destwb As Workbook
    Dim TempFilePath As String
    Dim TempFileName As String
    Dim I As Long

    With Application
        .ScreenUpdating = False
        .EnableEvents = False
    End With

    Set Sourcewb = ActiveWorkbook

    'Copy the sheet to a new workbook
    ActiveSheet.Copy
    Set Destwb = ActiveWorkbook

    'Determine the Excel version and file extension/format
    With Destwb
        If Val(Application.Version) < 12 Then
            'You use Excel 97-2003
            FileExtStr = ".xls": FileFormatNum = -4143
        Else
            'You use Excel 2007-2010, we exit the sub when your answer is
            'NO in the security dialog that you only see  when you copy
            'an sheet from a xlsm file with macro's disabled.
            If Sourcewb.Name = .Name Then
                With Application
                    .ScreenUpdating = True
                    .EnableEvents = True
                End With
                MsgBox "Your answer is NO in the security dialog"
                Exit Sub
            Else
                Select Case Sourcewb.FileFormat
                Case 51: FileExtStr = ".xlsx": FileFormatNum = 51
                Case 52:
                    If .HasVBProject Then
                        FileExtStr = ".xlsm": FileFormatNum = 52
                    Else
                        FileExtStr = ".xlsx": FileFormatNum = 51
                    End If
                Case 56: FileExtStr = ".xls": FileFormatNum = 56
                Case Else: FileExtStr = ".xlsb": FileFormatNum = 50
                End Select
            End If
        End If
    End With

    '    'Change all cells in the worksheet to values if you want
    '    With Destwb.Sheets(1).UsedRange
    '        .Cells.Copy
    '        .Cells.PasteSpecial xlPasteValues
    '        .Cells(1).Select
    '    End With
    '    Application.CutCopyMode = False

    'Save the new workbook/Mail it/Delete it
    TempFilePath = Environ$("temp") & ""
    TempFileName = "Part of " & Sourcewb.Name & " " _
                 & Format(Now, "dd-mmm-yy h-mm-ss")

    With Destwb
        .SaveAs TempFilePath & TempFileName & FileExtStr, _
                FileFormat:=FileFormatNum
        On Error Resume Next
        For I = 1 To 3
            .SendMail "", _
                      ""
            If Err.Number = 0 Then Exit For
        Next I
        On Error GoTo 0
        .Close SaveChanges:=False
    End With

    'Delete the file you have send
    Kill TempFilePath & TempFileName & FileExtStr

    With Application
        .ScreenUpdating = True
        .EnableEvents = True
    End With
End Sub

Option Explicit
Sub Luca01()
Dim AppMail As Object 'Outlook.Application
Dim NewMail As Object 'Outlook.Application
Dim miaDir
Dim MioWBK As Workbook
Dim MioSheet As Worksheet
Dim Nome As String
Dim Cognome As String
Dim indirizziTO As String
Dim IndirizziCC As String
Dim NomeFile As String
Dim Oggetto As String
Dim Testo As String

Set MioWBK = ActiveWorkbook
Set MioSheet = ActiveWorkbook.Sheets("SINTESI")
miaDir = MioWBK.Path
Nome = MioSheet.Range("B3")
Cognome = MioSheet.Range("B4")
NomeFile = "SINTESI_" & Nome & "_" & Cognome & ".pdf"

ActiveWorkbook.ExportAsFixedFormat Type:=xlTypePDF, Filename:= _
        miaDir & "/" & NomeFile, Quality:= _
        xlQualityStandard, IncludeDocProperties:=False, IgnorePrintAreas:=False, _
        OpenAfterPublish:=False

On Error Resume Next
Set AppMail = GetObject(, "Outlook.Application")
If Err.Number <> 0 Then
    Err.Clear
    Set AppMail = CreateObject("Outlook.Application")
    AppMail.Session.Logon

    If Err <> 0 Then
        MsgBox "Could not load Outlook", vbOKOnly + vbInformation, "Error report"
        End
    End If
End If
indirizziTO = MioSheet.Range("B6")
IndirizziCC = ""
Set NewMail = AppMail.CreateItem(0)

Oggetto = "Invio Documentazione"
Testo = "Egregio Signor " & Cognome & " " & Nome & vbCrLf
Testo = Testo & "Le Invio la documentazione allegata:" & vbCrLf
Testo = Testo & " - " & NomeFile & vbCrLf & vbCrLf
Testo = Testo & "Cordiali Saluti" & vbCrLf

With NewMail
    .To = indirizziTO
    .CC = IndirizziCC
    .Subject = Oggetto
    .body = Testo & .body
    .Attachments.Add miaDir & "/" & NomeFile
    .Display
End With

'NewMail.SEND
End Sub