usare un CONCATENATE per ottenere stringhe testo

Hai un problema con Excel?

Nuova discussione

usare un CONCATENATE per ottenere stringhe testo
di Ciccio (utente non iscritto) data: 17/05/2017 16:38:10
Buonasera,
cortesemente, avrei bisogno di un aiuto per utilizzare la funzione CONCATENATE in modo da ottenere delle stringhe a lunghezza fissa.
riporto un esempio per far capire cosa vorrei ottenere.
nelle righe dalla 14 alla 16 (da utilizzare poi su migliaia di righe) riporto quello che vorrei ottenere rispettando le seguenti indicazioni:
- lunghezza fissa di ciascun campo con zeri avanti;
- riportare anche gli spazi;
- mantenere la data così come riportata aaaammgg;
- riportare anche i segni + e - davanti ai numeri della colonna L

uso excel in inglese e non so usare le macro perciò pensavo di utilizzare il CONCATENATE, ma perdo la lunghezza fissa dei campi.
vi sare molto grato se mi aiutaste ad impstare la formula

grazie
saluti
di cromagno data: 17/05/2017 17:21:52
Ciao,
i dati "originali" li hai ottenuti tramite formattazione delle celle, per la formula, devi usare la funzione TESTO().

Quindi, nella cella B14 (da copiare poi in basso) puoi usare:
=CONCATENA(TESTO(B4;"00000");";";TESTO(C4;"000000000000000");";";D4;";";E4;"; ";F4;";";G4;";";TESTO(H4;"000000000");";";TESTO(I4;"aaaammgg");";";TESTO(J4;"aaaammgg");";";TESTO(K4;"aaaammgg");";";SE(L4>=0;"+";"");TESTO(L4;"000000000000"))

ti riallego il file...

Ciao
Tore
di Luca73 data: 17/05/2017 17:28:20
Prova con il file allegato

OOOPs non avevo visto la risposta di Cromagno (che saluto) e la mia mi sembra pressochè identica tranne alcuni dettagli....

=CONCATENA(TESTO(B4;"00000");";";TESTO(C4;RIPETI("0";15));";";SE(D4="";" ";D4);";";E4;";";
RIPETI(" ";6-LUNGHEZZA(F4))&F4;";";TESTO(G4;"0000");";";TESTO(H4;RIPETI("0";9));";";
TESTO(I4;"aaaammgg");";";TESTO(J4;"aaaammgg");";";TESTO(K4;"aaaammgg");";";
TESTO(L4*100;"+000000000000;-000000000000");CODICE.CARATT(32))

Ciao
Luca
di cromagno data: 17/05/2017 17:49:25
Ciao Luca
di Ciccio (utente non iscritto) data: 18/05/2017 18:56:56
Grazie mille Luca e Tore,

Fantastico!!!! Risolto

Ciao

Vuoi Approfondire?